[Unicode]   CLDR Charts Home | Site Map | Search
 

¤Xhosa-Xhosa (IPA Phonetics)

CLDR Version 29β Index

Lists data fields that differ from the last version. Inherited differences in locales are suppressed, except where the source locales are different. The collations and metadata still have a raw format. The rbnf, segmentations, and annotations are not yet included.

PathOldNew
…/transforms/transform[@source="xh"][@target="xh_FONIPA"][@direction="forward"]/_alias▷missing◁xh-fonipa-t-xh
…/transforms/transform[@source="xh"][@target="xh_FONIPA"][@direction="forward"]/_visibility▷missing◁external
…/transforms/transform[@source="xh"][@target="xh_FONIPA"][@direction="forward"]/tRule▷missing◁# Pronunciation rules for isiXhosa.
#
# Author: mjansche@google.com (Martin Jansche)
#
# These rules transcribe isiXhosa into the phoneme inventory used within the
# NCHLT Speech Corpus (https://sites.google.com/site/nchltspeechcorpus/home).
#
# The rules were tested using the NCHLT-inlang isiXhosa pronunciation dictionary
# (http://rma.nwu.ac.za/index.php/resource-catalogue/nchlt-inlang-dictionaries.html).
# They correctly account for 14,999 out of 15,000 entries in the dictionary.
#
# The NCHLT 2013 phone set does not distinguish short and long vowels and does
# not indicate tone in any way. Transcription of tone is out of scope without a
# dictionary, since tone is generally not indicated in the orthography. Nasal
# clicks are not treated as separated phonemes in the NCHLT 2013 phone set and
# are transcribed as a sequence of nasal plus click instead.
#
# One minor notational deviation from the NCHLT 2013 phone set is that we use a
# tie bar within the complex (slack voiced) clicks, e.g. ɡ͡ǀ instead of ɡǀ, to
# avoid ambiguity and make the phoneme inventory uniquely decodable.

::Lower;

nyh → ɲʰ;
n { tsh → t͡ʃʼ;
tsh → t͡ʃʰ;
tyh → cʰ;

bh → bʰ;
ch → ǀʰ;
dl → ɮ;
dy → ɟ;
gc → ɡ͡ǀ;
gq → ɡ͡ǃ;
gr → ɣ;
gx → ɡ͡ǁ;
hl → ɬ;
kh → kʰ;
kr → k͡x;
mh } [^l] → mʰ; # denotes /mɬ/ instead
nh → nʰ;
ny → ɲ;
ph → pʰ;
qh → ǃʰ;
sh → ʃ;
th → tʰ;
tl → t͡ɬʼ;
ts → t͡sʼ;
ty → cʼ;
xh → ǁʰ;

aa → | a;
ee → | e;
ii → | i;
kc → | c;
kq → | q;
mm → | m;
oo → | o;
rh → | r;
uu → | u;

a → a;
b → ɓ;
c → ǀ;
d → d;
e → ɛ;
f → f;
g → ɡ;
h → h;
i → i;
j → d͡ʒ;
k → kʼ;
l → l;
m → m;
n } g → ŋ;
n → n;
o → ɔ;
p → pʼ;
q → ǃ;
r → r;
s → s;
t → tʼ;
u → u;
v → v;
w → w;
x → ǁ;
y → j;
z → z;