Re: which is the best UTF mailer

From: John Delacour (JD@Eremita.demon.co.uk)
Date: Sun Sep 15 2002 - 20:01:10 EDT

At 6:50 pm +0100 15/9/02, Michael Everson wrote:

>At 10:38 +0100 2002-09-14, John Delacour wrote:
>
>>I can also send UTF-8 encoded mail from Eudora using another 'personality'
>
>How?

     tell app "Eudora"
      if not (exists the personality "UTF-8") then
       set p to make the personality -- ! it is CASesEnsItive
       set the name of the result to "UTF-8"
      end
      set utf8 to a reference to the personality "UTF-8"
      tell utf8
       set its setting 9018 to "UTF-8"
      end
      set msg to make message at the end of mailbox 2
      set s to "ΘΕμ”½ηΘΕέ”††ΤΊε”††”ΌγΑΗ†ΘΕμΛΔεΘΕέ”††ΤΊε”½ηΒθΨ”ͺ€ΑΗ†ΘΕμ"
      set s to s & return & return
      set s to s & "‘†‘±·‡ ·Ίκ‘‡‘½‘¨‘₯‘΅ ‘†‘±·‡ ·Ίκ‘‡ ¦Ρ·ψα ¦α‘Ό‘ͺ‘Ό‘‚¦"
      set s to s & "Ρ‘±‘Ό ¦Δ‘ψ¦Ε‘΅‘Ψ·ζ„, ·Ί£‘‡ ‘₯‘Ό‘΅‘ͺ‘…‘ͺ¦η‘½‘±‘Ί‘΅‘‡"
      set s to s & ", ‘΅·‡κ ¦Δ¦Ε‘¨¦Ρ¦Ρ¦β‘Ί‘΅‘‡."
      tell the msg
       set its personality to utf8
       set its QP to true
       set its field "subject" to "UTF-8 Test"
       set its field "" to s
      end
     end

You now have a personality that you can use whenever you send UTF-8.
The message must be plain text containing raw utf-8. The same can be
done for JIS, html, UTF-7 and virtually anything. Eudora's potential
is limitless.

>>and received UTF-8 messages can be displayed, at the click of a
>>button, in Apple's Unicode editor TextEdit (OS X) or, in OS 8.6+,
>>in WorldText.
>
>Explain, please "at the click of a button".... UTF-8 messages don't
>display in Eudora, which is a very, very, very bad thing. I'm a
>registered (paid) user of Eudora and have queried Tech Support
>several times and never had a single response, which is most
>irritating.

Write to the man himself, Steve Dorner <sdorner@qualcomm.com>.

You have a toolbar in Eudora which can run any script in your Script
menu. Set your toolbar vertical, names only, with or without small
icons, so that you have a column of buttons 110 pixels wide down the
left hand side of your screen. 15 of these can be activated with
function keys.

Place the following script in your Scripts folder in the folder
"Eudora Stuff" and relaunch Eudora. Create a new button on the
toolbar and when prompted, select "Convert UTF-8" from the menu.

Now whenever you send or receive mail in UTF-8, you can view it
instantly in TextEdit. The process is very fast. To use this script
you must have the TEC Osax, which is available for both OS Old and OS
10. Search Google for "TEC OSAX" with the quotes and follow the
instructions.

       ----- Script "Convert UTF-8" -----
       tell app "Eudora"
        if not (outgoing of front message) then
         set show all headers of front message to false
        else
         save front window
        end
        set s to get field "" of front message
       end
       set s to TECConvertText s fromCode "UTF-8" toCode "UNICODE-2-0"
       set f to "" & (path to temporary items) & "Eudora Message"
       open for access file f with write permission
       set eof file f to 0
       write (ASCII character 254) & (ASCII character 255) to file f
       write s to file f
       close access file f
       tell application "Finder"
        open file f using application file id "com.apple.textedit"
       end
       tell app "TextEdit" to activate
       -----

>>I am not sure how quickly Eudora will move to Unicode.
>
>Not quickly enough.

If enough people make a noise in the right places, it will happen more quickly.

JD

This archive was generated by hypermail 2.1.2 : Sun Sep 15 2002 - 20:46:34 EDT